Arduino应用开发——SD卡

发布于:2023-01-22 ⋅ 阅读:(7) ⋅ 点赞:(0) ⋅ 评论:(0)

Arduino应用开发——SD卡

前言

存储设备是我们在做嵌入式开发时经常用到的,常用的如flash、eeprom、SD卡、U盘等。SD卡的好处是容量大,读写速度相对较快(可以使用SDIO或SPI接口通信)。之前我也有介绍过flash的使用,那这一讲主要讲解一下SD卡的使用。
注:因为我这里只有ESP32和ESP8266,这两个MCU都是没有SDIO接口的,所以这里就以SPI接口来讲解了。

1 硬件介绍

1.1 模块简介

本文只测试了ESP32的SPI读写SD卡。
注:如果要用其他MCU,如ESP8266,实际上读写的流程是完全一样的,只有SPI的接口引脚号以及SPI库有略微区别,稍做修改即可。

硬件配置如下:

模块 型号 说明
ESP32 ESP-WROOM-32 MCU是乐鑫的一款芯片,开发板型号ESP32 DEVKITV1
MicroSD 这个SD模组只有2个IC,1个是电压LDO,1个是MOS集成IC,所以实际通信是直接通过SPI访问SD卡的

下图是我在某宝买的一个SD卡通用模组,电路非常简单,就只有几个器件,所以这里就不再具体介绍了。
在这里插入图片描述

1.2 硬件连接

ESP32 MicroSD 说明
VCC VCC 电源正,3.3V
GND GND 电源负
GPIO18\SPI_CLK CLK SPI时钟线
GPIO23\SPI_MOSI MOSI SPI数据线,ESP32输出,SD卡输入
GPIO19\SPI_MISO MISO SPI数据线,ESP32输入,SD卡输出
GPIO5\SPI_CS CS SPI片选
提示:模块上面的丝印是直接对应MCU那边的,也就是说不需要MOSI接MISO这样反一下

本文主要讲解软件部分开发,硬件部分也比较简单,这里就不在这里具体介绍了。

2 软件编程和测试

版本说明:
本文测试时各软件使用的版本如下:

软件 版本 备注
Arduino IDE 1.8.16 Arduino IDE
ESP32 package 2.0.1 建议使用2.0.0或以上版本的ESP32 package,2.0.0以下版本不兼容esp32-s2及esp32-c2

2.1 Arduino IDE环境搭建

Arduino开发板库安装
esp8266和esp32开发板环境搭建具体就不说了,不懂的同学可以看下我之前发布的博客。
esp8266开发入门教程(基于Arduino)——环境安装
ESP32 Arduino开发环境搭建
使用VS code搭建Arduino IDE环境

2.2 SD库API介绍

我这里只列举常用的几个函数,具体的介绍可以看下官方的SD库。

函数 说明 示例 函数原形
begin() 初始化函数,可以根据实际使用入参(片选引脚,SPI引脚等),不入参的话按默认配置 SD.begin(); SD.begin(4); begin(uint8_t ssPin, SPIClass &spi, uint32_t frequency, const char * mountpoint, uint8_t max_files, bool format_if_empty)
cardType() 读取SD卡类型 card_type = SD.cardType(); sdcard_type_t SDFS::cardType()
open() 打开指定路径或文件 fs.open(“/test.txt”); File FS::open(const String& path, const char* mode, const bool create)
remove() 删除文件 fs.remove(“/test.txt”); bool FS::remove(const char* path)
write() 往文件里写数据 file.write(“hello world”); size_t File::write(const uint8_t *buf, size_t size)
read() 从文件里读数据 size = file.read(buf, 10); size_t File::read(uint8_t* buf, size_t size)
mkdir() 创建目录 fs.mkdir(“/”); bool FS::mkdir(const String &path)

2.3 测试示例

我这里先直接用官方库提供的示例做一个测试,官方库这里基于常用的几个API做了一个封装,添加了很多调试信息,对可能出现的一些错误操作也做了提示(如:在读写之前会先判断文件是否正确打开),使得整个文件操作的流程更加完善,所以这套demo里面有很多细节都是值得参考的。
示例代码:

#include "FS.h"
#include "SD.h"
#include "SPI.h"

void listDir(fs::FS &fs, const char * dirname, uint8_t levels){
    Serial.printf("Listing directory: %s\n", dirname);

    File root = fs.open(dirname);
    if(!root){
        Serial.println("Failed to open directory");
        return;
    }
    if(!root.isDirectory()){
        Serial.println("Not a directory");
        return;
    }

    File file = root.openNextFile();
    while(file){
        if(file.isDirectory()){
            Serial.print("  DIR : ");
            Serial.println(file.name());
            if(levels){
                listDir(fs, file.path(), levels -1);
            }
        } else {
            Serial.print("  FILE: ");
            Serial.print(file.name());
            Serial.print("  SIZE: ");
            Serial.println(file.size());
        }
        file = root.openNextFile();
    }
}

void createDir(fs::FS &fs, const char * path){
    Serial.printf("Creating Dir: %s\n", path);
    if(fs.mkdir(path)){
        Serial.println("Dir created");
    } else {
        Serial.println("mkdir failed");
    }
}

void removeDir(fs::FS &fs, const char * path){
    Serial.printf("Removing Dir: %s\n", path);
    if(fs.rmdir(path)){
        Serial.println("Dir removed");
    } else {
        Serial.println("rmdir failed");
    }
}

void readFile(fs::FS &fs, const char * path){
    Serial.printf("Reading file: %s\n", path);

    File file = fs.open(path);
    if(!file){
        Serial.println("Failed to open file for reading");
        return;
    }

    Serial.print("Read from file: ");
    while(file.available()){
        Serial.write(file.read());
    }
    file.close();
}

void writeFile(fs::FS &fs, const char * path, const char * message){
    Serial.printf("Writing file: %s\n", path);

    File file = fs.open(path, FILE_WRITE);
    if(!file){
        Serial.println("Failed to open file for writing");
        return;
    }
    if(file.print(message)){
        Serial.println("File written");
    } else {
        Serial.println("Write failed");
    }
    file.close();
}

void appendFile(fs::FS &fs, const char * path, const char * message){
    Serial.printf("Appending to file: %s\n", path);

    File file = fs.open(path, FILE_APPEND);
    if(!file){
        Serial.println("Failed to open file for appending");
        return;
    }
    if(file.print(message)){
        Serial.println("Message appended");
    } else {
        Serial.println("Append failed");
    }
    file.close();
}

void renameFile(fs::FS &fs, const char * path1, const char * path2){
    Serial.printf("Renaming file %s to %s\n", path1, path2);
    if (fs.rename(path1, path2)) {
        Serial.println("File renamed");
    } else {
        Serial.println("Rename failed");
    }
}

void deleteFile(fs::FS &fs, const char * path){
    Serial.printf("Deleting file: %s\n", path);
    if(fs.remove(path)){
        Serial.println("File deleted");
    } else {
        Serial.println("Delete failed");
    }
}

void testFileIO(fs::FS &fs, const char * path){
    File file = fs.open(path);
    static uint8_t buf[512];
    size_t len = 0;
    uint32_t start = millis();
    uint32_t end = start;
    if(file){
        len = file.size();
        size_t flen = len;
        start = millis();
        while(len){
            size_t toRead = len;
            if(toRead > 512){
                toRead = 512;
            }
            file.read(buf, toRead);
            len -= toRead;
        }
        end = millis() - start;
        Serial.printf("%u bytes read for %u ms\n", flen, end);
        file.close();
    } else {
        Serial.println("Failed to open file for reading");
    }


    file = fs.open(path, FILE_WRITE);
    if(!file){
        Serial.println("Failed to open file for writing");
        return;
    }

    size_t i;
    start = millis();
    for(i=0; i<2048; i++){
        file.write(buf, 512);
    }
    end = millis() - start;
    Serial.printf("%u bytes written for %u ms\n", 2048 * 512, end);
    file.close();
}

void setup(){
    Serial.begin(115200);
    if(!SD.begin()){
        Serial.println("Card Mount Failed");
        return;
    }
    uint8_t cardType = SD.cardType();

    if(cardType == CARD_NONE){
        Serial.println("No SD card attached");
        return;
    }

    Serial.print("SD Card Type: ");
    if(cardType == CARD_MMC){
        Serial.println("MMC");
    } else if(cardType == CARD_SD){
        Serial.println("SDSC");
    } else if(cardType == CARD_SDHC){
        Serial.println("SDHC");
    } else {
        Serial.println("UNKNOWN");
    }

    uint64_t cardSize = SD.cardSize() / (1024 * 1024);
    Serial.printf("SD Card Size: %lluMB\n", cardSize);

    listDir(SD, "/", 0);
    createDir(SD, "/mydir");   // 创建一个目录/mydir
    listDir(SD, "/", 0);
    removeDir(SD, "/mydir");   // 删除/mydir目录
    listDir(SD, "/", 2);
    writeFile(SD, "/hello.txt", "Hello ");    // 打开\创建一个hello.txt文件,并在文件开头写入"Hello "
    appendFile(SD, "/hello.txt", "World!\n"); // 在hello.txt文件末尾继续写入"World!",然后换行
    readFile(SD, "/hello.txt");               // 读取hello.txt文件的内容并打印出来
    deleteFile(SD, "/foo.txt");               // 删除foo.txt文件(提示:该目录下没有foo.txt文件,应该会提示错误)
    renameFile(SD, "/hello.txt", "/foo.txt"); // 把hello.txt文件重命名为foo.txt
    readFile(SD, "/foo.txt");                 // 读取foo.txt文件的内容并打印出来
    testFileIO(SD, "/test.txt");              // 测试文件读写速度
    Serial.printf("Total space: %lluMB\n", SD.totalBytes() / (1024 * 1024));  // 读取并打印SD卡的总容量
    Serial.printf("Used space: %lluMB\n", SD.usedBytes() / (1024 * 1024));    // 读取并打印SD卡的剩余容量
}

void loop(){

}

测试结果:
通过串口打印可以看到以下信息:
在这里插入图片描述

如果硬件异常或者接线不对,会出现通讯异常,提示如下:
在这里插入图片描述

3 结束语

好了,关于如何基于Arduino使用SD卡就介绍到这里,内容不多,讲的也比较简单,如果还有什么问题,欢迎在评论区留言或者私信给我。

想了解更多Arduino的内容,可以关注一下博主,后续我还会继续分享更多的经验给大家。
esp8266基于Arduino的开发教程汇总:
https://blog.csdn.net/ShenZhen_zixian/article/details/121659482

如果这篇文章能够帮到你,就…你懂得。
请添加图片描述